川合孝典です。

長い上にオフトピだとは思うのですが、ご勘弁を
----- Original Message -----
From: "Tybalt of Capulet" <ice-man@xxxxxxxxxx>
To: <ml@xxxxxxxxxx>
Sent: Thursday, September 19, 2002 1:02 AM
Subject: [mysql 06223] Re: スレッド式掲示板のテーブル構造について


> 神崎です。
>
> みなさま貴重なご回答ありがとうございます。
>
> 個人的には川合さんの
>
> > 実際に表示する場合には
> > SELECT * FROM BBS
> >   ORDER BY oyano DESC, resno
> >
> > あたりで取り出して、プログラム内部でmsgno、resnoを見て
> > 並べ替えています。
>
> の方法が非常に気になりますがいくら考えてもロジックが全く思い浮かびません。
> 提示できるロジック等ございますでしょうか？
（以下略）
ＰＨＰでも今やってますが、余分なコードがついているのでPerlで説明します。
コードの解説はここではしません。（コメントでだいたいわかるかと思います）

#[スクリプト]
#以下のような行を表すとして
#---------(1)
#  ---------(2)
#    ---------(3)
#      ---------(4)
#  ---------(5)
#    ---------(6)
#      ---------(7)
#    ---------(8)
#      ---------(9)
#        ---------(10)
use strict;
my @aRows= (
# [識別子,スレッド開始MSG,参照MSG]
  [1, 1, 1], [2, 1, 1], [3, 1, 2],
  [4, 1, 3], [5, 1, 1], [6, 1, 5],
  [7, 1, 6], [8, 1, 5], [9, 1, 8],
  [10, 1, 9]);
#最初に（スレッド順）＋参照しているメッセージNo順に並べ替え
@aRows = sort {$a->[2] <=> $b->[2]} @aRows;
#ここまではORDER BYを使って指定したつもりで。

my $raRow;
my @aRes=();
foreach $raRow (@aRows) { #ここは一件ずつ取り出しているつもり
    #自分自身を参照しているときには、そのまま末尾に追加
    if($raRow->[0] == $raRow->[2]) {
        push @aRes, [ @$raRow, 0];
    }
    else {
        my $iPos;
        #結果を入れる配列を末尾からなめる
        for($iPos=$#aRes; $iPos >=0; --$iPos){
            #参照MSGが同じであれば、その直後にレベルを１つ下げて追加
            if($aRes[$iPos][0] == $raRow->[2]) {
                splice(@aRes, $iPos+1, 0, [ @$raRow, $aRes[$iPos][3]+1]);
                last;
            }
            #同じMSGを参照しているのであれば、その直後に同じレベルで追加
            elsif($aRes[$iPos][2] == $raRow->[2]) {
                splice(@aRes, $iPos+1, 0, [ @$raRow, $aRes[$iPos][3]]);
                last;
            }
        }
    }
}
my $raItm;
my $sPad;
#できたものを表示
foreach $raItm (@aRes){
    $sPad = '   ' x $raItm->[3]; #レベルにあわせてインデント
    print $sPad, '---------(' , $raItm->[0], ")\n";
}

__END__

[実行結果]
---------(1)
   ---------(2)
      ---------(3)
         ---------(4)
   ---------(5)
      ---------(6)
         ---------(7)
      ---------(8)
         ---------(9)
            ---------(10)

===================================================
川合 孝典 (Hippo2000)
   DBI日本語メーリングリスト管理人、Kansai.pm所属
   kwitknr@xxxxxxxxxx GCD00051@xxxxxxxxxx
   http://member.nifty.ne.jp/hippo2000、http://www.hippo2000.info/
「Cマガジン」でPerl DBIの連載はじまります。
   http://www.cmagazine.jp/
===================================================